Polski Portal COLOBOTa - Zobacz temat

FE4R · Wysłany: 01-11-2009, 22:07 **Program dla robota obsługującego hutę.**

Hej...

Tak, tak... wiem, że pipok ma taki temat 2 linijki niżej, ale ja jestem narcyz, lubię mieć swój temat dla swojego programu.

Stworzyłem trochę bardziej rozbudowany program do zbierania rudy tytanu niż ten, który przysyłają Wam z Houston podczas misji.

Założenia:

1) Standardowe:

*robot znajdzie rudę
*robot znajdzie hutę
*robot podniesie tytan i odłoży w wolnym miejscu

2) Mniej standardowe:

*na początku robot wyrzuci to, co ma w uchwycie
*robot sprawdzi, czy są obiekty potrzebne do produkcji
*robot powiadomi o kłopotach w wykonaniu procesu wiadomościami
*robot po dojściu do huty i zastaniu tam gotowego tytanu nie spanikuje, tylko odniesie tytan w wolne miejsce, a potem kontynuuje pracę z rudą
*robot dwa razy sprawdzi, czy ma wystarczająco energii

Objaśnienia:
NA KOŃCU POSTU.

Oto wersja obrazkowa:
http://img689.imageshack....collect2000.png

A oto wersja tekstowa:
(Czy jest lepszy sposób na pokazanie programu? Ma on 5 bloków i ten sposób nie jest zbyt przejrzysty.)

Kod:

extern void object::Collect2000()
{
errmode(0);

if(this.load != null)
{
drop();
}

while(radar(TitaniumOre) != null)
{
ipf(40);

object o, c, t;

o = radar(TitaniumOre);

if(energyCell.energyLevel < 0.3)
{
object p;

p = radar(PowerStation);

if(p != null)
{
goto(p.position);

do
{
wait(0.1);
}
while(energyCell.energyLevel < 1);
}
else
{
message("Potrzebuje ogniwa - robot od tytanu!");

do
{
wait(5);
}
while(energyCell.energyLevel < 1);
}

}

goto(o.position);
grab();

c = radar(Converter);

if(c != null)
{
goto(c.position);

t = search(Titanium, c.position);

if(t != null)
{
if(distance(t.position, c.position) < 6)
{
turn(90);
drop();
turn(-90);
grab();
goto(space(position));
drop();

o = radar(TitaniumOre);
goto(o.position);
grab();

goto(c.position);
drop();

}
}

drop();
move(-3.5);

do
{
wait(1);
}
while(radar(Titanium, 0, 15, 0, 6) == null);

move(3.5);
grab();

goto(space(position));
drop();

if(energyCell.energyLevel < 0.3)
{
object p;

p = radar(PowerStation);

if(p != null)
{
goto(p.position);

do
{
wait(0.1);
}
while(energyCell.energyLevel < 1);
}
else
{
message("Potrzebuje ogniwa - robot od tytanu!");

do
{
wait(5);
}
while(energyCell.energyLevel < 1);
}

}
}
else
{
message("Brak huty!");
break;
}

}

wait(2);
message("Brak rudy tytanu!");
}

Objaśnienia:

1) Początkowe sprawdzanie - czy robot ma coś w chwytaku?

Dlaczego użyłem bardzo prostego sprawdzenia czy robot ma coś w chwytaku? pipok zakładał bodajże, że sprawdzi najpierw czy przedmiot w chwytaku, jeśli istnieje, to ruda tytanu. Jeśli tak, to robot odniesie ją do huty. Ale to jest już zadanie pętli 'while', aby się tym zająć. Dlatego robotowi uprościłem zadanie - zamiast sprawdzać, co ma w chwytaku, wyrzuci, to co ma. Jeśli jest to ruda - następna pętla i tak nakaże mu to podnieść. W końcu to najbliższy kawałek rudy. A poza tym ze znanego programu 'SwitchCell' wiadomo, iż funkcje takie jak 'grab()' czy drop()' nie kosztują robota ani grama energii.

2) Po co funkcja ipf?

Nie wiem, jak z waszymi procesorami, ale mój ma się dobrze z takim ipf, a robot jako tako wychodzi na tym dobrze.

3) Dlaczego robot sprawdza czy ma pełną baterię, zanim zacznie proces?

Zdarzało mi się tak, że robot nie docierał do elektrowni przed skończeniem procesu tworzenia tytanu, a zatem bateria kończyła mu się zanim dotarł do sprawdzania baterii. Poza tym robot na początku nie musi mieć pełnego ogniwa. Dla usprawnienia mogłem dać program na każdym kroku robota, jednakże nie zawsze się to opłaca, gdy elektrownia jest blisko i jesteś pewny, że robot dojdzie. Później spróbuję opracować program, który liczy zużycie energii poszczególnych napędów(dla ścisłości robotów z fabryki, a nie takich podrasowanych w 'CreateObject').

4) Co to za blok ze zmienną 't'?

Zmienna 't' określa tytan. Ale nie byle jaki. Określa tytan, który czasami robot potrafi tam zastać po przybyciu do hut z rudą tytanu. W takiej sytuacji odpowiednio się zachowa i odniesie tytan w bezpieczne miejsce, a potem wróci do rudy.

5) Po co te wiadomości od robota?

Otóż ja zazwyczaj gram tak, iż mam: roboty obronne i ofensywne, czyli działa, 1 robota chwytaka latającego - do wszystkiego, od produce do zbierania tytanu w wolnym czasie(on również nadzoruje wszelkie prace) oraz robota szperacza, który zazwyczaj stoi koło radaru i na nim trzymam programy typu 'prędkościomierz'. Otóż, gdy taka wiadomość się pojawi - używam latającego chwytaka, aby osobiście(czyli na sterowaniu ręcznym najszybciej i najprecyzyjniej) wymienić mu ogniwo czy postawić hutę / kopalnię, gdy czegoś brakuje.

**Usprawnienia programu**

Ponieważ program, który napisałem zajął mi może kilka minut, więc jest daleki od perfekcji. Tutaj postaram się zapisać listę rzeczy / pomysłów na usprawnienie robota.

- Zwiększenie samodzielności związanej z ogniwem i jego wyczerpaniem.

- Funkcja do uciekania do najbliższego bezpiecznego miejsca, gdy jakikolwiek wróg zbliży się na ~50 metrów (chociaż osobiście zostawiłbym obronę innych robotów robotom, które od tego są - działom)

- Funkcja zatrzymania produkcji, jeśli tytanu jest więcej niż potrzeba.

- Odwołując się do powyższej linijki - stworzenie funkcji, która rozpocznie produkcję ogniw atomowych(jeśli można), gdy tytanu jest już wystarczająco.

- Dla robotów latających - opanowanie temperatury silników oraz mocy ogniwa.
( z silnikami będzie problem, gdyż nie da się tego przewidzieć - jedyne wartości jakie zwraca temperatura silnika to '0' lub '1')

Pozdrawiam,
FE4R

pipok · Dołączył: 24 Cze 2009 Posty: 53

FE4R · Wysłany: 03-11-2009, 17:12 **Re: Program dla robota obsługującego hutę.**

pipok · Dołączył: 24 Cze 2009 Posty: 53

adiblol · Wysłany: 03-11-2009, 21:24

pipok · Dołączył: 24 Cze 2009 Posty: 53

Ach, to! No, niestety, jedyna metoda, żeby było niezależnie od tego parametru, to program, gdzie bot przemieszcza się na większe dystanse tylko poprzez korzystanie z motor() i jet(), ze sprawdzaniem temperatury na bieżąco.

PS. Ale dla nowych botów, skonstruowanych podczas misji, i tak jest range ma standardową wartość...

FE4R · Wysłany: 03-11-2009, 23:01 **Re: Program dla robota obsługującego hutę.**

pipok · Dołączył: 24 Cze 2009 Posty: 53

FE4R · Wysłany: 05-11-2009, 23:41

Biore poprawki i tworze co raz wiecej funkcji, aby uproscic glowna funkcje maksymalnie.
Jednak jest kilka bledow, ktore opisze ponizej.

Znowu przepraszam za brak polskich znakow - angielski laptop.

Kod:

extern void object::CollectTitaniumV3()
{
errmode(0);

ipf(90);

int surowiec, produkt;

surowiec = TitaniumOre;
produkt = Titanium;

if(this.load != null)
{
if(this.load.category == surowiec)
{
Proces();
}

if(this.load.category == produkt);
{
Store();
}

if(this.load.category != produkt)
{
drop();
}
}

while(true)
{
while(radar(surowiec) != null)
{
object ore;

ore = radar(surowiec);

if(ore != null)
{
Recharge();

goto(ore.position);
grab();

Proces();
}
else
{
message("Brak surowca!");
wait(1);
}
}
}
}

void object::Proces()
{
object conv = radar(Converter);

if(conv != null)
{
Recharge();

goto(conv.position);

Check();

move(-4);

do
{
wait(1);
}
while(radar(Titanium, 0, 20, 0, 6) == null);

move(4);
grab();

Store();

Recharge();

}
else
{
message("Brak przetworni!");
}

}

void object::Store()
{
object store;

store = radar(RedFlag);

goto(space(store.position, 0, 20, 3));
drop();
}

void object::Check()
{
if(radar(Titanium, 0, 30, 0, 6) != null)
{
object ore = search(TitaniumOre, position), conv = radar(Converter);

turn(90);
drop();
turn(-90);
grab();

Store();

goto(ore.position);
grab();

goto(conv.position);
drop();
}
else
{
drop();
}
}

void object::Recharge()
{
if(energyCell.energyLevel < 0.3)
{
if(this.energyCell.category == NuclearCell)
{
NuclearRecharge();
}

if(this.energyCell.category == PowerCell)
{
object px = radar(PowerStation);

if(px != null)
{
errmode(0);

int err;

err = goto(px.position);

if(err != 0)
{
turn(direction(px.position));
move(distance(position, px.position) - 4);

do
{
wait(1);
}
while(err != 0);
move(4);

do
{
wait(1);
}
while(energyCell.energyLevel < 1);
}
}
else
{
NuclearRecharge();
}
}
}
}

void object::NuclearRecharge()
{
object cell = radar(NuclearCell);

if(cell != null)
{
goto(cell.position);
grab();
drop(Behind);
grab(EnergyCell);
drop();
grab(Behind);
drop(EnergyCell);
}
else
{
cell = radar(PowerCell);

if(cell != null)
{
goto(cell.position);
grab();
drop(Behind);
grab(EnergyCell);
drop();
grab(Behind);
drop(EnergyCell);
}
else
{
message("Na planecie nie ma zrodel energii!");
}
}
}

Jednak jest kilka problemow, z ktorymi musze sie uporac, zanim program bedzie w niezawodny.

1. Program czasami sie urywa po zakonczeniu funkcji 'Store', jakby 'while(true)' nie istnialo.

2. Problem, ktory pipok juz wspomnial. Robot, jesli przypadkiem znajdzie gotowy tytan w hucie, odklada go przy czerwonej fladze, ale nie wraca do kawalka, ktory zostawil przy hucie, ale do kawalka przy kopalni(gdyz jest blizej), POMIMO ze ruda przy hucie zostala przypisana do zmiennej 'ore'. Czemu wiec zmienna zamienia obiekt z rudy przy hucie na rudzie przy kopalni? Oczywiscie gdy robot wezmie rude z kopalni i uda sie do huty, zastanie tam drugi kawalek, ktory wywola blad i zatrzyma program.

3. Stworzylem rowniez pewien warunek w funkcji 'Recharge()' z errmode(0), ktorego nie jestem pewien.
Potem tworze petle do i robot czeka, az blad minie, a gdy usuwam robota blokujacego elektrownie, zbieracz dalej czeka 4 metry przed. Nie rusza sie. Nie wiem, co zrobic.

Mam nadzieje, ze po skonczeniu tych poprawek zajme sie robotem latajacym i program bedzie prawie gotowy i idealny.

Pozdrawiam,
FE4R

pipok · Dołączył: 24 Cze 2009 Posty: 53

Nigdzie nie przywracasz standardowej reakcji na błędy: errmode(1). Lepiej unikać takiego podejścia, bo nie wiesz, w którym, miejscu i z jakiego powodu pojawiają się kłopoty. Powinno się wyłączać standardową obsługę błędów tylko w wybranych miejscach, gdzie wiadomo, że może się pojawić błąd i gdzie jest zaplanowane działanie, które rozwiązuje problem.

Pomijając programy dla obcych istot w COLOBOCIE, bo wtedy lepiej żeby mrówka zrobiła coś głupiego albo się zapętliła na nicnierobieniu, niż żeby walnęła komunikatem o błędzie.

Przykład niedopracowanej obsługi błędów:

Kod:

errmode(0);
int err;
err = goto(px.position);
if(err != 0)
{
turn(direction(px.position));
move(distance(position, px.position) - 4);

do
{
wait(1);
}
while(err != 0);
move(4);

Mianowicie: jeśli goto(px.position) się nie powiedzie (czyli err!=0), to późniejsze move(4) nie zostanie NIGDY wykonane. Program utknie w nieskończonej pętli czekania. Dlaczego? Ponieważ oczekiwanie (wait(1)) jest powtarzane w pętli tak długo, jak długo wartość zmiennej err jest niezerowa. A ona się wewnątrz tej pętli nie zmieni! Ta zmienna wciąż ma tę samą wartość, równą kodowi błędu, jaki wystąpił podczas goto(px.position).
Poprawne rozwiązanie powinno wyglądać mniej więcej tak:

Kod:

int err;
errmode(0);
err = goto(px.position);
errmode(1); // !!!
if(err != 0)
{
turn(direction(px.position));
errmode(0); // bo wykonanie 'move' moze sie nie udac
move(distance(position, px.position) - 4);
// ale jesli sie nie uda, to nie ma problemu,
// niech bot zostanie, gdzie jest (i tak ma czekac).
// Dlatego nawet nie analizujemy, czy sie udalo
errmode(1);

do
{
wait(1);
// sprobuj znowu dostac sie do elektrowni
errmode(0); err = goto(px.position); errmode(1);
}
while(err != 0); // ponawiaj proby, jesli sie nie udaje
// w tym miejscu jest pewne, ze goto() sie udalo,
// czyli bot jest w hucie